Scheme - 手続きによる抽象の構築(高階手続きによる抽象(値として返される手続き(反復改良法(iterative improvement))))

計算機プログラムの構造と解釈[第2版]
原著

開発環境

• macOS Sierra - Apple (OS)
• Emacs (Text Editor)
• Scheme (プログラミング言語)
• kscheme (ksi)(github) (処理系)

計算機プログラムの構造と解釈[第2版](ハロルド エイブルソン (著)、ジュリー サスマン (著)、ジェラルド・ジェイ サスマン (著)、Harold Abelson (原著)、Julie Sussman (原著)、Gerald Jay Sussman (原著)、和田 英一 (翻訳)、翔泳社、原著: Structure and Interpretation of Computer Programs (MIT Electrical Engineering and Computer Science)(SICP))の第1章(手続きによる抽象の構築)、1.3(高階手続きによる抽象)、1.3.4(値として返される手続き)、問題1.46.を取り組んでみる。

その他参考書籍

• Instructor's Manual to Accompany Structure & Interpretation of Computer Programs

問題1.46.

コード(Emacs)

(begin
  (load "procedures.scm")
  (newline)
  (define (p x) (display x) (newline))
  
  (define tolerance 0.00001)
  (define (iterative-improve close-enough? improve)
    (define (iter x)
      (if (close-enough? x)
          x
          (iter (improve x))))
    iter)

  (define (average x y) (/ (+ x y) 2))
  (define (sqrt x)
    ((iterative-improve
      (lambda (guess)
        (< (abs (- (square guess) x)) tolerance))
      (lambda (guess)
        (average guess (/ x guess))))
     x))

  (define (fixed-point f first-guess)
    ((iterative-improve
      (lambda (guess)
        (< (abs (- guess (f guess))) tolerance))
      f)
     first-guess))
        
  (define (average-damp f)
    (lambda (x) (average x (f x))))

  (define (compose f g)
    (lambda (x) (f (g x))))

  (define (repeated proc n)
    (if (= n 1)
        (lambda (x) (proc x))
        (compose proc (repeated proc (- n 1)))))

  (define (n-root n x)
    (fixed-point ((repeated average-damp n)
                  (lambda (y) (/ x (expt y (- n 1)))))
                 1.0))
  (define nums '(1 2 3 4 5 6 7 8 9 10))
  (p 'sqrt)
  (for-each (lambda (n)
              (p (+ 0.0 (sqrt n))))
            nums)

  (p 'fixed-point)
  (for-each (lambda (n)
              (p (n-root 2 n)))
            nums)
  'done)

入出力結果(Terminal(kscheme), REPL(Read, Eval, Print, Loop))

$ ksi < sample46.scm
ksi> 
sqrt
1.0
1.41421568627451
1.732050810014728
2.000000092922295
2.236068895643364
2.449489742787552
2.645751311111369
2.828427125049864
3.000000001396984
3.162277665175675
fixed-point
1.0
1.414195849664585
1.7320385479067
1.999986653772061
2.236055093026562
2.44947855954401
2.645734499650577
2.828408508355658
3.0
3.162288665505404
=> done
ksi> $