Scheme - 超言語的抽象(超循環評価器(内部定義(内部定義, let, letrecを使わずに再帰手続き(階乗, Fibonacci数)を定義する方法)))

計算機プログラムの構造と解釈[第2版]
(翔泳社)
ハロルド エイブルソン (著) ジュリー サスマン (著)
ジェラルド・ジェイ サスマン (著)
Harold Abelson (原著) Julie Sussman (原著)
Gerald Jay Sussman (原著) 和田 英一 (翻訳)

開発環境

• OS X Mavericks - Apple(OS)
• Emacs (CUI)、BBEdit - Bare Bones Software, Inc. (GUI) (Text Editor)
• Scheme (プログラミング言語)
• Gauche (処理系)

計算機プログラムの構造と解釈[第2版](ハロルド エイブルソン (著)、ジュリー サスマン (著)、ジェラルド・ジェイ サスマン (著)、Harold Abelson (原著)、Julie Sussman (原著)、Gerald Jay Sussman (原著)、和田 英一 (翻訳)、翔泳社、原書: Structure and Interpretation of Computer Programs (MIT Electrical Engineering and Computer Science)(SICP))の4(超言語的抽象)、4.1(超循環評価器)、4.1.6(内部定義)、問題 4.21.を解いてみる。

その他参考書籍

• Instructor's Manual to Accompany Structure & Interpretation of Computer Programs
• プログラミングGauche (Kahuaプロジェクト (著), 川合 史朗 (監修), オライリージャパン)

問題 4.21.

コード(BBEdit, Emacs)

sample21.scm

#!/usr/bin/env gosh
;; -*- coding: utf-8 -*-

;; a.
(print "10の階乗")
(print
 ((lambda (n)
    ((lambda (fact)
       (fact fact n))
     (lambda (ft k)
       (if (= k 1)
           1
           (* k (ft ft (- k 1)))))))
  10))

(print "Fibonacci数")
;; Fibonacci数
(define fib
  (lambda (n)
    ((lambda (fib)
       (fib fib n))
     (lambda (fb k)
       (cond ((= k 0) 0)
             ((= k 1) 1)
             (else (+ (fb fb (- k 1))
                      (fb fb (- k 2)))))))))

(for-each (lambda (n)
            (print n ": " (fib n)))
          '(0 1 2 3 4 5 6 7 8 9 10))

;; b.
(define (f x)
  ((lambda (even? odd?)
     (even? even? odd? x))
   (lambda (ev? od? n)
     (if (= n 0)
         #t
         (od? ev? od? (- n 1))))
   (lambda (ev? od? n)
     (if (= n 0)
         #f
         (ev? ev? od? (- n 1))))))

(print "偶数かどうか判定")
(for-each (lambda (x)
            (print x ": " (f x)))
          '(0 1 2 3 4 5 6 7 8 9 10))

入出力結果(Terminal(gosh), REPL(Read, Eval, Print, Loop))

$ ./sample21.scm
10の階乗
3628800
Fibonacci数
0: 0
1: 1
2: 1
3: 2
4: 3
5: 5
6: 8
7: 13
8: 21
9: 34
10: 55
偶数かどうか判定
0: #t
1: #f
2: #t
3: #f
4: #t
5: #f
6: #t
7: #f
8: #t
9: #f
10: #t
$