Scheme - 標準部品化力、オブジェクトおよび状態(ストリーム(ストリームパラダイムの開発(対の無限のストリーム(Ramanujan number))))

計算機プログラムの構造と解釈[第2版]
(翔泳社)
ハロルド エイブルソン (著) ジュリー サスマン (著)
ジェラルド・ジェイ サスマン (著)
Harold Abelson (原著) Julie Sussman (原著)
Gerald Jay Sussman (原著) 和田 英一 (翻訳)

開発環境

• OS X Mavericks - Apple(OS)
• Emacs (CUI)、BBEdit - Bare Bones Software, Inc. (GUI) (Text Editor)
• Scheme (プログラミング言語)
• Gauche (処理系)

計算機プログラムの構造と解釈[第2版](ハロルド エイブルソン (著)、ジュリー サスマン (著)、ジェラルド・ジェイ サスマン (著)、Harold Abelson (原著)、Julie Sussman (原著)、Gerald Jay Sussman (原著)、和田 英一 (翻訳)、翔泳社、原書: Structure and Interpretation of Computer Programs (MIT Electrical Engineering and Computer Science)(SICP))の3(標準部品化力、オブジェクトおよび状態)、3.5(ストリーム)、3.5.3(ストリームパラダイムの開発)、対の無限のストリーム、問題 3.71.を解いてみる。

その他参考書籍

• Instructor's Manual to Accompany Structure & Interpretation of Computer Programs
• プログラミングGauche (Kahuaプロジェクト (著), 川合 史朗 (監修), オライリージャパン)

問題 3.71.

コード(BBEdit, Emacs)

sample71.scm

#!/usr/bin/env gosh
;; -*- coding: utf-8 -*-

(load "./stream.scm")

(define (merge-weighted pairs1 pairs2 weight)
  (cond ((stream-null? pairs1) pairs2)
        ((stream-null? pairs2) pairs1)
        (else
         (let ((pairs1car (stream-car pairs1))
               (pairs2car (stream-car pairs2)))
           (if (< (weight pairs1car) (weight pairs2car))
               (cons-stream pairs1car
                            (merge-weighted (stream-cdr pairs1)
                                            pairs2
                                            weight))
               (cons-stream pairs2car
                            (merge-weighted pairs1
                                            (stream-cdr pairs2)
                                            weight)))))))

(define (weighted-pairs s t weight)
  (cons-stream
   (list (stream-car s) (stream-car t))
   (merge-weighted
    (stream-map (lambda (x)
                  (list (stream-car s) x))
                (stream-cdr t))
    (weighted-pairs (stream-cdr s)
                    (stream-cdr t)
                    weight)
    weight)))

(define stream (weighted-pairs integers
                               integers
                               (lambda (pair)
                                 (+ (expt (car pair) 3)
                                    (expt (cadr pair) 3)))))

(define (weighted pair) (+ (expt (car pair) 3)
                           (expt (cadr pair) 3)))

(define (ramanujan-filter s)
  (let ((scar (stream-car s))
        (scdr (stream-cdr s)))
    (let ((weight (weighted scar)))
      (if (= weight (weighted (stream-car scdr)))
          (cons-stream scar
                       (ramanujan-filter
                        (stream-filter
                         (lambda (pair)
                           (> (weighted pair) weight))
                         (stream-cdr scdr))))
          (ramanujan-filter scdr)))))

(define ramanujan (ramanujan-filter stream))

(define (enumerate-interval low high)
  (if (> low high)
      '()
      (cons low
            (enumerate-interval (+ low 1)
                                high))))

(define (test stream)
  (for-each (lambda (n)
              (let ((pair (stream-ref stream n)))
                (print (weighted pair) " " pair)))
            (enumerate-interval 0 5)))

(test ramanujan)

入出力結果(Terminal(gosh), REPL(Read, Eval, Print, Loop))

$ ./sample71.scm
1729 (9 10)
4104 (9 15)
13832 (18 20)
20683 (19 24)
32832 (18 30)
39312 (15 33)
$