Scheme - データによる抽象の構築(階層データ構造と閉包性(公認インターフェースとしての並び(並びの演算(matrix, vectorと基本演算))))

計算機プログラムの構造と解釈
Gerald Jay Sussman, Julie Sussman
Harold Abelson (原著) 和田 英一 (翻訳)

開発環境

• OS X Mavericks - Apple(OS)
• Emacs (CUI)、BBEdit - Bare Bones Software, Inc. (GUI) (Text Editor)
• Scheme (プログラミング言語)
• Gauche (処理系)

計算機プログラムの構造と解釈(Gerald Jay Sussman(原著)、Julie Sussman(原著)、Harold Abelson(原著)、和田 英一(翻訳)、ピアソンエデュケーション、原書: Structure and Interpretation of Computer Programs (MIT Electrical Engineering and Computer Science)(SICP))の2(データによる抽象の構築)、2.2(階層データ構造と閉包性)、2.2.3(公認インターフェースとしての並び)、並びの演算、問題 2.37.を解いてみる。

その他参考書籍

• Instructor's Manual to Accompany Structure & Interpretation of Computer Programs
• プログラミングGauche (Kahuaプロジェクト (著), 川合 史朗 (監修), オライリージャパン)

問題 2.37.

コード(BBEdit, Emacs)

sample.scm

#!/usr/bin/env gosh
;; -*- coding: utf-8 -*-

;; これまでに書いた手続き
(load "./procedures.scm")

(define (dot-product v w)
  (accumulate + 0 (map * v w)))

(define (matrix-*-vector m v)
  (map (lambda (w)
         (dot-product v w))
       m))

(define (transpose mat)
  (accumulate-n cons '() mat))

(define (matrix-*-matrix m n)
  (let ((cols (transpose n)))
    (map (lambda (v)
           (map (lambda (w)
                  (dot-product v w))
                cols))
         m)))

(define v1 '(1 2 3 4))
(define v2 '(4 5 6 6))
(define v3 '(6 7 8 9))
(define m (list v1 v2 v3))
(define n (list '(1 2)
                '(3 4)
                '(5 6)
                '(7 8)))

(for-each (lambda (v)
            (print "(matrix-*-vector " m " " v ") => "
                   (matrix-*-vector m v)))
          (list v1 v2 v3))

(print "(transpose " m ") => " (transpose m))

(print "(matrix-*-matrix " m " " n ") => "
       (matrix-*-matrix m n))

入出力結果(Terminal(gosh), REPL(Read, Eval, Print, Loop))

$ ./sample.scm
(matrix-*-vector ((1 2 3 4) (4 5 6 6) (6 7 8 9)) (1 2 3 4)) => (30 56 80)
(matrix-*-vector ((1 2 3 4) (4 5 6 6) (6 7 8 9)) (4 5 6 6)) => (56 113 161)
(matrix-*-vector ((1 2 3 4) (4 5 6 6) (6 7 8 9)) (6 7 8 9)) => (80 161 230)
(transpose ((1 2 3 4) (4 5 6 6) (6 7 8 9))) => ((1 4 6) (2 5 7) (3 6 8) (4 6 9))
(matrix-*-matrix ((1 2 3 4) (4 5 6 6) (6 7 8 9)) ((1 2) (3 4) (5 6) (7 8))) => ((50 60) (91 112) (130 160))
$